OpenFOAM を Excel から実行する

'''
' @brief JobListにジョブを登録
Private Sub Register_Click()
    With Application.FileDialog(msoFileDialogFolderPicker)
        If .Show = True Then
            Dim path: path = .SelectedItems(1)
            
            If CreateObject("Scripting.FileSystemObject").fileExists(path & "\Allrun") Then
                JobListBox.AddItem (path)
            Else
                MsgBox "指定されたフォルダ内にAllrunファイルが無いため登録できません。"
            End If
        End If
    End With
End Sub

'''
' @brief JobList内にあるジョブを順次実行
Private Sub Run_Click()
    If JobListBox.ListCount < 1 Then
        MsgBox "ジョブがありません。"
        Exit Sub
    End If
    
    MessageTextBox.Text = "Start." & vbCrLf
    Do
        If JobListBox.ListCount < 1 Then
            Exit Do
        End If

        Dim item: item = JobListBox.List(0)
        RunOpenFOAM item, MessageTextBox
        
        JobListBox.RemoveItem (0)
        FinishedJobListBox.AddItem (item)
        MessageTextBox.Text = MessageTextBox.Text & "----------" & vbCrLf
        
        DoEvents
    Loop
    
    MessageTextBox.Text = MessageTextBox.Text & "Done." & vbCrLf

    MsgBox "全てのジョブが終了しました。"
End Sub

'''
' @brief Windows形式のパスをBash on Winsowsでマウントされるパスに変換
' @param Windows形式のパス(ex. C:\MyFolder\MyFile)
' @param Bash on Winsowsでマウントされるパス(ex. /mnt/c/MyFolder/MyFile)
' @return 常にTrue
Function WindowsPathToLinuxPath(src)
    Dim regex: Set regex = CreateObject("VBScript.RegExp")
    
    ' ドライブレターを小文字に変換
    regex.Pattern = "[A-Z][:]"
    regex.Global = False
    Set Match = regex.Execute(src)
    If 0 < Match.Count Then
        src = Replace(src, Match(0), LCase(Match(0)))
    End If
    
    ' セパレーターを/に変換
    regex.Pattern = ":*\\"
    regex.Global = True
    Dim dest: dest = regex.Replace(src, "/")
    
    ' 先頭に/mnt/をつけて返す
    WindowsPathToLinuxPath = "/mnt/" & dest
End Function

'''
' @brief 指定されたOpenFOAM 用ケースを実行
' @param windowsPath[in] 実行するOpenFOAM用ケースフォルダパス(Windows形式パス)
' @param MessageTextBox[in|out] 標準出力、標準エラーを出力するためのテキストボックス
' @return 常にTrue
Function RunOpenFOAM(ByVal windowsPath, ByRef MessageTextBox)
    linuxPath = WindowsPathToLinuxPath(windowsPath)
    
    ' Bashで実行するコマンド
    linuxCmd = _
        "source /opt/openfoam4/etc/bashrc;" & _
        "cd " & linuxPath & ";" & _
        "./Allrun;"
    
    ' コマンドプロンプトで実行するコマンド
    Dim shell: Set shell = CreateObject("WScript.Shell")
    Dim winCmd: winCmd = "C:\Windows\sysnative\bash.exe -c """ & linuxCmd & """"

    Dim message
    Dim errorMessage

    ' コマンドを実行して終了するまでループで待機
    Dim wExec: Set wExec = shell.Exec("%ComSpec% /c " & winCmd)
    Do While wExec.Status = 0
        ' 標準出力を出力
        message = wExec.StdOut.ReadAll
        If message <> "" Then
            MessageTextBox.Text = MessageTextBox.Text & message & vbCrLf
        End If
        
        ' 標準エラーを出力
        errorMessage = wExec.stderr.ReadAll
        If errorMessage <> "" Then
            MessageTextBox.Text = MessageTextBox.Text & errorMessage & vbCrLf
        End If
        
        DoEvents
    Loop

    ' 標準出力に文字列が残っている場合を考えて出力
    message = wExec.StdOut.ReadAll
    If message <> "" Then
        MessageTextBox.Text = MessageTextBox.Text & message & vbCrLf
    End If
    
    ' 標準エラーに文字列が残っている場合を考えて出力
    errorMessage = wExec.stderr.ReadAll
    If errorMessage <> "" Then
        MessageTextBox.Text = MessageTextBox.Text & errorMessage & vbCrLf
    End If
    
    RunOpenFOAM = True
End Function

C:\Windows\sysnative\bash.exe -c "（実行したい Linux コマンド）"